/******************** BLYNK ****************************/
#define BLYNK_TEMPLATE_ID "TMPL3mghbJXjJ"
#define BLYNK_TEMPLATE_NAME "smart door lock"
#define BLYNK_AUTH_TOKEN "1j3ZtbLBVQf7OmXStJRja-288iwrgBjE"

#include <WiFi.h>
#include <BlynkSimpleEsp32.h>
#include <ESP32Servo.h>
#include <LiquidCrystal_I2C.h>
#include <Keypad.h>
#include <Password.h>

char ssid[] = "Wokwi-GUEST";
char pass[] = "";

BlynkTimer timer;


/******************** SERVO ****************************/
#define SERVO_PIN 15

Servo servo;


/******************** LCD ******************************/
LiquidCrystal_I2C lcd(0x27,16,2);


/******************** KEYPAD ***************************/
const byte ROWS = 4;
const byte COLS = 4;

char keys[ROWS][COLS] =
{
  {'1','2','3','A'},
  {'4','5','6','B'},
  {'7','8','9','C'},
  {'*','0','#','D'}
};


byte rowPins[ROWS] = {23,19,18,5};
byte colPins[COLS] = {17,16,4,2};


Keypad keypad = Keypad(makeKeymap(keys),
rowPins,colPins,ROWS,COLS);


/******************** PASSWORD *************************/
Password password("1111");

bool isDoorLocked = true;

byte maxPasswordLength = 6;
byte currentPasswordLength = 0;


/******************** FUNCTION DECLARATION *************/
void processNumberKey(char key);
void doorOpen();
void doorLocked();
void resetPassword();
void displayMessage(String a,String b);
void sendDoorStatus();
void checkConnection();



/******************** BLYNK CONNECT ********************/
BLYNK_CONNECTED()
{
  Serial.println("Blynk Connected");

  Blynk.syncVirtual(V0);

  sendDoorStatus();
}



/******************** BLYNK SWITCH *********************/
BLYNK_WRITE(V0)
{
  int state = param.asInt();


  if(state == 1)
  {
    servo.write(180);

    isDoorLocked = false;

    lcd.clear();
    lcd.print("Door OPEN");

    Blynk.virtualWrite(V1,"OPEN");
    Blynk.virtualWrite(V2,1);
  }

  else
  {
    servo.write(10);

    isDoorLocked = true;

    lcd.clear();
    lcd.print("Door LOCKED");

    Blynk.virtualWrite(V1,"LOCKED");
    Blynk.virtualWrite(V2,0);
  }


  delay(1000);
  lcd.clear();
}



/******************** SEND STATUS **********************/
void sendDoorStatus()
{

  if(isDoorLocked)
  {
    Blynk.virtualWrite(V1,"LOCKED");
    Blynk.virtualWrite(V2,0);
  }

  else
  {
    Blynk.virtualWrite(V1,"OPEN");
    Blynk.virtualWrite(V2,1);
  }

}



/******************** CONNECTION CHECK *****************/
void checkConnection()
{
  if(!Blynk.connected())
  {
    Serial.println("Reconnecting...");
    Blynk.connect();
  }
}



/******************** SETUP ****************************/
void setup()
{

  Serial.begin(115200);


  servo.setPeriodHertz(50);
  servo.attach(SERVO_PIN,500,2400);

  // Initial lock position
  servo.write(10);



  lcd.init();
  lcd.backlight();


  lcd.setCursor(0,0);
  lcd.print("Smart Door Lock");

  lcd.setCursor(0,1);
  lcd.print("Connecting...");



  // Blynk connection
  Blynk.begin(BLYNK_AUTH_TOKEN,ssid,pass);



  lcd.clear();
  lcd.print("Blynk Connected");

  delay(1000);

  lcd.clear();



  timer.setInterval(2000L,sendDoorStatus);
  timer.setInterval(5000L,checkConnection);

}



/******************** LOOP *****************************/
void loop()
{

  Blynk.run();

  timer.run();



  lcd.setCursor(0,0);


  if(isDoorLocked)
  {
    lcd.print("DOOR LOCKED ");
  }

  else
  {
    lcd.print("DOOR OPEN   ");
  }



  char key = keypad.getKey();



  if(key != NO_KEY)
  {

    delay(100);


    if(key == '#')
    {
      resetPassword();
    }


    else if(key == '*')
    {

      if(isDoorLocked)
      {
        doorOpen();
      }

      else
      {
        doorLocked();
      }

    }


    else
    {
      processNumberKey(key);
    }

  }

}



/******************** PASSWORD INPUT *******************/
void processNumberKey(char key)
{

  if(currentPasswordLength < maxPasswordLength)
  {

    lcd.setCursor(currentPasswordLength+5,1);

    lcd.print("*");


    password.append(key);

    currentPasswordLength++;

  }

}



/******************** OPEN DOOR ************************/
void doorOpen()
{

  if(password.evaluate())
  {

    servo.write(180);

    isDoorLocked=false;


    Blynk.virtualWrite(V0,1);
    Blynk.virtualWrite(V1,"OPEN");
    Blynk.virtualWrite(V2,1);


    displayMessage("Password OK",
                   "Door OPEN");

  }


  else
  {

    displayMessage("Wrong Password",
                   "Try Again");

  }


  resetPassword();

}



/******************** LOCK DOOR ************************/
void doorLocked()
{

  if(password.evaluate())
  {

    servo.write(10);


    isDoorLocked=true;


    Blynk.virtualWrite(V0,0);
    Blynk.virtualWrite(V1,"LOCKED");
    Blynk.virtualWrite(V2,0);



    displayMessage("Password OK",
                   "Door LOCKED");

  }


  else
  {

    displayMessage("Wrong Password",
                   "Try Again");

  }


  resetPassword();

}



/******************** RESET ****************************/
void resetPassword()
{

  password.reset();

  currentPasswordLength=0;

  lcd.clear();

}



/******************** LCD MESSAGE **********************/
void displayMessage(String line1,String line2)
{

  lcd.clear();


  lcd.setCursor(0,0);
  lcd.print(line1);


  lcd.setCursor(0,1);
  lcd.print(line2);


  delay(2000);


  lcd.clear();

}