#include <WiFi.h>
#include <PubSubClient.h>
#include <Ticker.h>
#include <LiquidCrystal.h>

LiquidCrystal lcd(5, 21, 23, 22, 26, 13); //RS,E,D5,D6,D7,D8 diğer uçlar ve R/W GND
//1 -> 26 , 3 -> 13 kullanıldı

// WiFi ve MQTT Bilgileri
const char* ssid = "Wokwi-GUEST";
const char* password = "";
const char* mqttServer = "151.250.232.219";
const char* mqtt_user = "";
const char* mqtt_pass = "";
const int port = 1883;

// Pin Tanımlamaları
const int pinGreen = 32; //32
const int doorSensorPin = 34; //34
const int wifiStatus = 2;

// MT8870 DTMF Pinleri
const int Q1 = 16; //16
const int Q2 = 17; //17
const int Q3 = 18; //18
const int Q4 = 19; //19
const int StD = 15;//15 hata veriyor 25 kullanıldı

char keys[16] = {
  '1', '2', '3', 'A',
  '4', '5', '6', 'B',
  '7', '8', '9', 'C',
  '*', '0', '#', 'D'
};

// DTMF Değişkenleri
volatile bool yeniTusVar = false;
String girilenRakamlar = "";
int secilenDaireIndex = -1;

// Daire Seçim Zamanlayıcısı Değişkenleri
unsigned long daireSecimZamani = 0;
const unsigned long daireSecimZorunluSure = 25000; // 25 saniye LCD TIMEOUT

// Daire Tanımlamaları
struct Daire {
  String tuslananKod;
  String mqttEtiketi;
  String blok;
  String daireNo;
};

Daire daireListesi[] = {
  {"0101", "A11", "A1", "1"}, {"0102", "A12", "A1", "2"}, {"0103", "A13", "A1", "3"}, {"0104", "A14", "A1", "4"},
  {"0105", "A15", "A1", "5"}, {"0106", "A16", "A1", "6"}, {"0107", "A17", "A1", "7"}, {"0108", "A18", "A1", "8"},
  {"0201", "A21", "A2", "1"}, {"0202", "A22", "A2", "2"}, {"0203", "A23", "A2", "3"}, {"0204", "A24", "A2", "4"},
  {"0205", "A25", "A2", "5"}, {"0206", "A26", "A2", "6"}, {"0207", "A27", "A2", "7"}, {"0208", "A28", "A2", "8"},
  {"0301", "B11", "B1", "1"}, {"0302", "B12", "B1", "2"}, {"0303", "B13", "B1", "3"}, {"0304", "B14", "B1", "4"},
  {"0305", "B15", "B1", "5"}, {"0306", "B16", "B1", "6"}, {"0307", "B17", "B1", "7"}, {"0308", "B18", "B1", "8"},
  {"0401", "B21", "B2", "1"}, {"0402", "B22", "B2", "2"}, {"0403", "B23", "B2", "3"}, {"0404", "B24", "B2", "4"},
  {"0405", "B25", "B2", "5"}, {"0406", "B26", "B2", "6"}, {"0407", "B27", "B2", "7"}, {"0408", "B28", "B2", "8"},
  {"0501", "C11", "C1", "1"}, {"0502", "C12", "C1", "2"}, {"0503", "C13", "C1", "3"}, {"0504", "C14", "C1", "4"},
  {"0505", "C15", "C1", "5"}, {"0506", "C16", "C1", "6"}, {"0507", "C17", "C1", "7"}, {"0508", "C18", "C1", "8"},
  {"0601", "C21", "C2", "1"}, {"0602", "C22", "C2", "2"}, {"0603", "C23", "C2", "3"}, {"0604", "C24", "C2", "4"},
  {"0605", "C25", "C2", "5"}, {"0606", "C26", "C2", "6"}, {"0607", "C27", "C2", "7"}, {"0608", "C28", "C2", "8"},
  {"0701", "D11", "D1", "1"}, {"0702", "D12", "D1", "2"}, {"0703", "D13", "D1", "3"}, {"0704", "D14", "D1", "4"},
  {"0705", "D15", "D1", "5"}, {"0706", "D16", "D1", "6"}, {"0707", "D17", "D1", "7"}, {"0708", "D18", "D1", "8"},
  {"0801", "D21", "D2", "1"}, {"0802", "D22", "D2", "2"}, {"0803", "D23", "D2", "3"}, {"0804", "D24", "D2", "4"},
  {"0805", "D25", "D2", "5"}, {"0806", "D26", "D2", "6"}, {"0807", "D27", "D2", "7"}, {"0808", "D28", "D2", "8"}
};
const int daireSayisi = sizeof(daireListesi) / sizeof(daireListesi[0]);

char clientId[50];
WiFiClient espClient;
PubSubClient client(espClient);
Ticker relayTimer;

unsigned long lastPublishTime = 0;
const long interval = 2000;
bool lastSentState = HIGH;

// Status LED için Zamanlayıcı Değişkenleri
unsigned long lastLedBlinkTime = 0;
bool ledState = LOW;

// Wi-Fi bağlantı denemesi için zamanlayıcılar
unsigned long lastWifiCheck = 0;
const unsigned long wifiInterval = 10000; // 10 saniyede bir bağlanmayı dene

void IRAM_ATTR stdInterrupt() {
  yeniTusVar = true;
}

void turnOffRelay() {
  digitalWrite(pinGreen, LOW);
  Serial.println("Zaman Doldu: Röle otomatik KAPATILDI");
  if (WiFi.status() == WL_CONNECTED && client.connected()) {
    client.publish("role/lock", "OFF");
  }
}

void updateStatusLED() {
  bool wifiOk = (WiFi.status() == WL_CONNECTED);
  bool mqttOk = client.connected();

  if (wifiOk && mqttOk) {
    digitalWrite(wifiStatus, HIGH); // Wi-Fi ve MQTT Bağlı -> Sürekli YANAR
  }
  else if (wifiOk && !mqttOk) {
    // Sadece Wi-Fi Bağlı -> Yanıp Söner (250ms aralıkla)
    if (millis() - lastLedBlinkTime >= 250) {
      lastLedBlinkTime = millis();
      ledState = !ledState;
      digitalWrite(wifiStatus, ledState);
    }
  }
  else {
    digitalWrite(wifiStatus, LOW); // İnternet yoksa -> SÖNÜK
  }
}

void lcdDefaultEkran() {
  lcd.clear();
  lcd.setCursor(2, 0);
  lcd.print("HOSGELDiNiZ");
  lcd.setCursor(0, 1);
  lcd.print("Kod: ");
}

void setup() {
  Serial.begin(115200);
  snprintf(clientId, sizeof(clientId), "ESP32-%ld", random(1000000));

  pinMode(pinGreen, OUTPUT);
  digitalWrite(pinGreen, LOW);
  pinMode(doorSensorPin, INPUT);
  pinMode(wifiStatus, OUTPUT);

  pinMode(Q1, INPUT_PULLDOWN);
  pinMode(Q2, INPUT_PULLDOWN);
  pinMode(Q3, INPUT_PULLDOWN);
  pinMode(Q4, INPUT_PULLDOWN);
  pinMode(StD, INPUT);
  attachInterrupt(digitalPinToInterrupt(StD), stdInterrupt, RISING);

  lcd.begin(16, 2);
  //lcd.backlight();
  lcdDefaultEkran();

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password); // İlk açılış denemesi

  client.setServer(mqttServer, port);
  client.setCallback(callback);
}

// char dtmfToChar(int n) {
//   if (n == 10 || n == 0) return '0';
//   if (n >= 1 && n <= 9) return (char)(n + '0');
//   if (n == 11) return '*';
//   if (n == 12) return '#';
//   return ' ';
// }

void checkDTMF() {
  if (yeniTusVar) {
    delay(200); // Debounce süresi
    int sayi = (digitalRead(Q4) << 3) | (digitalRead(Q3) << 2) | (digitalRead(Q2) << 1) | digitalRead(Q1);
    //char tus = dtmfToChar(sayi);
    char tus = keys[sayi];
    yeniTusVar = false;

    if (tus == ' ') return;

    Serial.print("Tuşlandı: "); Serial.println(tus);

    // İnternetsiz modda dairenin '*' tuşuna basmasını beklediğimiz aşama
    if (secilenDaireIndex != -1) {
      if (tus == '*') {
        // --- YEREL KAPI AÇMA (İnternetsiz mod) ---
        digitalWrite(pinGreen, HIGH);
        relayTimer.once(1.5, turnOffRelay); // 1.5 saniye sonra otomatik kapat

        lcd.clear();
        lcd.setCursor(0, 0);
        lcd.print("Kapi Acildi!");
        delay(2000);

        // Sıfırla
        girilenRakamlar = "";
        secilenDaireIndex = -1;
        lcdDefaultEkran();
      }
      else if (tus == '#') {
        // İptal Et
        girilenRakamlar = "";
        secilenDaireIndex = -1;
        lcdDefaultEkran();
      }
      return;
    }

    // Normal Kod Girme Aşaması
    if (tus >= '0' && tus <= '9') {
      girilenRakamlar += tus;

      lcd.setCursor(0, 1);
      lcd.print("Kod: " + girilenRakamlar + "    ");

      if (girilenRakamlar.length() == 4) {
        daireyiBulVeIslemYap(girilenRakamlar);
      }
    }
    else if (tus == '#') {
      // Temizle
      girilenRakamlar = "";
      lcdDefaultEkran();
    } else if (tus == '*') {
      // --- HER DURUMDA KAPI AÇMA (DTMF)---
      digitalWrite(pinGreen, HIGH);
      relayTimer.once(1.5, turnOffRelay); // 1.5 saniye sonra otomatik kapat

      lcd.clear();
      lcd.setCursor(0, 0);
      lcd.print("Kapi Acildi!");
      delay(2000);

      // Sıfırla
      girilenRakamlar = "";
      secilenDaireIndex = -1;
      lcdDefaultEkran();
    }
  }
}

void daireyiBulVeIslemYap(String kod) {
  bool bulundu = false;
  for (int i = 0; i < daireSayisi; i++) {
    if (daireListesi[i].tuslananKod == kod) {
      bulundu = true;
      secilenDaireIndex = i;
      daireSecimZamani = millis();

      // KONTROL: İnternet ve MQTT bağlı mı?
      if (WiFi.status() == WL_CONNECTED && client.connected()) {
        // İNTERNET VAR: Direkt MQTT topic gönder, * bekleme
        char tpc[50];
        sprintf(tpc, "daire/%s/open", daireListesi[i].mqttEtiketi.c_str());
        client.publish(tpc, "DING");
        //daireSecimZamani = millis(); // 25 saniyelik sayacı başlat

        lcd.clear();
        lcd.setCursor(0, 0);
        lcd.print(daireListesi[i].blok + " Blok D:" + daireListesi[i].daireNo);
        lcd.setCursor(0, 1);
        lcd.print("Zil caliniyor...");
        delay(2000);
        // Sıfırla ve ana ekrana dön
        girilenRakamlar = "";
      }
      else {
        // İNTERNET YOK: '*' tuşunu beklemek üzere indexi ve zamanı kaydet
        // secilenDaireIndex = i;
        // daireSecimZamani = millis(); // 25 saniyelik sayacı başlat

        lcd.clear();
        lcd.setCursor(0, 0);
        lcd.print(daireListesi[i].blok + " Blok D:" + daireListesi[i].daireNo);
        lcd.setCursor(0, 1);
        lcd.print("* Bekleniyor...");
      }
      break;
    }
  }

  if (!bulundu) {
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Tanimsiz Daire!");
    delay(2000);
    girilenRakamlar = "";
    lcdDefaultEkran();
  }
}

void loop() {
  unsigned long currentMillis = millis();

  // Seçilen daire için 25 saniye zaman aşımı kontrolü
  if (secilenDaireIndex != -1) {
    if (currentMillis - daireSecimZamani >= daireSecimZorunluSure) {
      girilenRakamlar = "";
      secilenDaireIndex = -1;
      lcdDefaultEkran();
      Serial.println("25 sn süre doldu: Daire seçim ekranı zaman aşımına uğradı.");
    }
  }

  if (WiFi.status() == WL_CONNECTED) {
    if (!client.connected()) {
      mqttReconnect();
    }
    client.loop();
  } else {
    // Wi-Fi kopuksa belirli aralıklarla yeniden bağlanmayı dene
    if (currentMillis - lastWifiCheck >= wifiInterval) {
      lastWifiCheck = currentMillis;
      WiFi.begin(ssid, password);
    }
  }

  updateStatusLED();
  checkDTMF();

  // Kapı Sensörü Mantığı (Sadece internet/MQTT bağlıysa veri gönder)
  bool currentDoorState = digitalRead(doorSensorPin);

  if (currentDoorState == LOW) {
    if (currentMillis - lastPublishTime >= interval) {
      lastPublishTime = currentMillis;
      if (WiFi.status() == WL_CONNECTED && client.connected()) {
        client.publish("door/status", "DOOROPEN");
      }
      lastSentState = LOW;
    }
  }
  else if (currentDoorState == HIGH && lastSentState == LOW) {
    if (WiFi.status() == WL_CONNECTED && client.connected()) {
      client.publish("door/status", "DOORCLOSE");
    }
    lastSentState = HIGH;
  }
}

void callback(char* topic, byte* message, unsigned int length) {
  String payload = "";
  for (unsigned int i = 0; i < length; i++) payload += (char)message[i];
  if (payload == "ON") {
    secilenDaireIndex = -1;
    digitalWrite(pinGreen, HIGH);
    Serial.println("Kapı Açıldı..");
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.print("Kapi Acildi!");
    delay(2000);
    lcdDefaultEkran();
    relayTimer.once(1.5, turnOffRelay);
  } else if (payload == "OFF") {
    digitalWrite(pinGreen, LOW);
    relayTimer.detach();
  }
}

void mqttReconnect() {
  static unsigned long lastReconnectAttempt = 0;
  if (millis() - lastReconnectAttempt > 5000) {
    lastReconnectAttempt = millis();
    if (client.connect(clientId, mqtt_user, mqtt_pass)) {
      client.subscribe("role/lock");
      Serial.println("MQTT Bagli");
    }
  }
}