/*
  Example of UI localization. Based on basic menu example using GEM library. Using rotary encoder as an input source.

  Simple two page menu with one editable menu item associated with int variable, one with bool variable,
  and a button, pressing of which will result in int variable value printed to Serial monitor if bool variable is set to true.

  Second menu page with language option select is added.

  U8g2lib library is used to draw menu.
  KeyDetector library (version 1.2.0 or later) is used to detect rotary encoder operation.
  
  Additional info (including the breadboard view) available on GitHub:
  https://github.com/Spirik/GEM
  
  This example code is in the public domain.
*/

#include <GEM_u8g2.h>
#include <KeyDetector.h>

// Define signal identifiers for three outputs of encoder (channel A, channel B and a push-button)
#define KEY_A 1
#define KEY_B 2
#define KEY_C 3

// Pins encoder is connected to
const byte channelA = 2;
const byte channelB = 3;
const byte buttonPin = 4;

byte chanB = HIGH; // Variable to store Channel B readings

// Array of Key objects that will link GEM key identifiers with dedicated pins
// (it is only necessary to detect signal change on a single channel of the encoder, either A or B;
// order of the channel and push-button Key objects in an array is not important)
Key keys[] = {{KEY_A, channelA}, {KEY_C, buttonPin}};
//Key keys[] = {{KEY_C, buttonPin}, {KEY_A, channelA}};

// Create KeyDetector object
// KeyDetector myKeyDetector(keys, sizeof(keys)/sizeof(Key));
// To account for switch bounce effect of the buttons (if occur) you may want to specify debounceDelay
// as the third argument to KeyDetector constructor.
// Make sure to adjust debounce delay to better fit your rotary encoder.
// Also it is possible to enable pull-up mode when buttons wired with pull-up resistors (as in this case).
// Analog threshold is not necessary for this example and is set to default value 16.
KeyDetector myKeyDetector(keys, sizeof(keys)/sizeof(Key), /* debounceDelay= */ 5, /* analogThreshold= */ 16, /* pullup= */ true);

bool secondaryPressed = false;  // If encoder rotated while key was being pressed; used to prevent unwanted triggers
bool cancelPressed = false;  // Flag indicating that Cancel action was triggered, used to prevent it from triggering multiple times
const int keyPressDelay = 1000; // How long to hold key in pressed state to trigger Cancel action, ms
long keyPressTime = 0; // Variable to hold time of the key press event
long now; // Variable to hold current time taken with millis() function at the beginning of loop()

// Create an instance of the U8g2 library.
// Use constructor that matches your setup (see https://github.com/olikraus/u8g2/wiki/u8g2setupcpp for details).
// This instance is used to call all the subsequent U8g2 functions (internally from GEM library,
// or manually in your sketch if it is required).
// Please update the pin numbers according to your setup. Use U8X8_PIN_NONE if the reset pin is not connected
U8G2_SSD1306_128X64_NONAME_1_HW_I2C u8g2(U8G2_R0, /* reset=*/ U8X8_PIN_NONE);

// Create variables that will be editable through the menu and assign them initial values
int number = -512;
bool enablePrint = false;

// Create variable that will be editable through option select and create associated option select.
// This variable will hold currently selected language
byte lang = 0;
SelectOptionByte selectLangOptions[] = {{"En", 0}, {"Fr", 1}, {"De", 2}};
GEMSelect selectLang(sizeof(selectLangOptions)/sizeof(SelectOptionByte), selectLangOptions);

// Create menu item for option select with setLang() callback function
void setLang(); // Forward declaration
char* menuItemLangTitle[] = {"Language:", "Langue:", "Sprache:"};
GEMItem menuItemLang(menuItemLangTitle[lang], lang, selectLang, setLang);

// Create variable that will be editable through option select and create associated option select.
// This variable will be passed to menu.invertKeysDuringEdit(), and naturally can be presented as a bool,
// but is declared as a byte type to be used in an option select rather than checkbox (for demonstration purposes)
byte invert = 1;
SelectOptionByte selectInvertOptions[][2] = {
  {{"Invert", 1}, {"Normal", 0}},     // English
  {{"Inverti", 1}, {"Normal", 0}},    // French
  {{"Umgekehrt", 1}, {"Normal", 0}},  // Deutch (German)
};
GEMSelect selectInvert(sizeof(selectInvertOptions[lang])/sizeof(SelectOptionByte), selectInvertOptions[lang]);

// Create menu item for option select with applyInvert() callback function
void applyInvert(); // Forward declaration
char* menuItemInvertTitle[] = {"Chars order:", "Ordre des ca:", "Zeichenreih.:"};
GEMItem menuItemInvert(menuItemInvertTitle[lang], invert, selectInvert, applyInvert);

// Create two menu item objects of class GEMItem, linked to number and enablePrint variables
char* menuItemIntTitle[] = {"Number:", "Nombre:", "Nummer:"};
GEMItem menuItemInt(menuItemIntTitle[lang], number);
char* menuItemBoolTitle[] = {"Enable print:", "Imprimer:", "Drucken:"};
GEMItem menuItemBool(menuItemBoolTitle[lang], enablePrint);

// Create menu button that will trigger printData() function. It will print value of our number variable
// to Serial monitor if enablePrint is true. We will write (define) this function later. However, we should
// forward-declare it in order to pass to GEMItem constructor
void printData(); // Forward declaration
char* menuItemButtonTitle[] = {"Print", "Imprimer", "Drucken"};
GEMItem menuItemButton(menuItemButtonTitle[lang], printData);

// Create menu page object of class GEMPage. Menu page holds menu items (GEMItem) and represents menu level.
// Menu can have multiple menu pages (linked to each other) with multiple menu items each
char* menuPageMainTitle[] = {"Main Menu", "Menu principal", "Hauptmenü"};
GEMPage menuPageMain("Main Menu"); // Main page
char* menuPageSettingsTitle[] = {"Settings", "Paramètres", "Einstellungen"};
GEMPage menuPageSettings(menuPageSettingsTitle[lang]); // Settings submenu

// Create menu item linked to Settings menu page
char* menuItemMainSettingsTitle[] = {"Settings", "Parametres", "Einstellungen"};
GEMItem menuItemMainSettings(menuItemMainSettingsTitle[lang], menuPageSettings);

// Create menu object of class GEM_u8g2. Supply its constructor with reference to u8g2 object we created earlier
GEM_u8g2 menu(u8g2);
// Which is equivalent to the following call (you can adjust parameters to better fit your screen if necessary):
// GEM_u8g2 menu(u8g2, /* menuPointerType= */ GEM_POINTER_ROW, /* menuItemsPerScreen= */ GEM_ITEMS_COUNT_AUTO, /* menuItemHeight= */ 10, /* menuPageScreenTopOffset= */ 10, /* menuValuesLeftOffset= */ 86);

void setup() {
  // Pin modes
  pinMode(channelA, INPUT_PULLUP);
  pinMode(channelB, INPUT_PULLUP);
  pinMode(buttonPin, INPUT_PULLUP);

  // Serial communication setup
  Serial.begin(115200);

  // U8g2 library init.
  u8g2.begin();

  // Turn inverted order of characters during edit mode on (feels more natural when using encoder)
  menu.invertKeysDuringEdit(invert);

  // Menu init, setup and draw
  menu.init();
  setupMenu();
  menu.drawMenu();

  Serial.println("Initialized");
}

void setupMenu() {
  // Add menu items to Settings menu page
  menuPageSettings
    .addMenuItem(menuItemInvert)
    .addMenuItem(menuItemLang);

  // Add menu items to menu page
  menuPageMain
    .addMenuItem(menuItemMainSettings)
    .addMenuItem(menuItemInt)
    .addMenuItem(menuItemBool)
    .addMenuItem(menuItemButton);

  // Specify parent menu page for the Settings menu page
  menuPageSettings.setParentMenuPage(menuPageMain);

  // Add menu page to menu and set it as current
  menu.setMenuPageCurrent(menuPageMain);
}

byte detectEncoder() {
  byte btn = GEM_KEY_NONE;

  chanB = digitalRead(channelB); // Reading Channel B signal beforehand to account for possible delays due to polling nature of KeyDetector algorithm
  // Detect key press using KeyDetector library
  // and pass pressed button to menu
  myKeyDetector.detect();

  switch (myKeyDetector.trigger) {
    case KEY_A:
      // Signal from Channel A of encoder was detected
      if (chanB == LOW) {
        // If channel B is low then the knob was rotated CCW
        if (myKeyDetector.current == KEY_C) {
          // If push-button was pressed at that time, then treat this action as GEM_KEY_LEFT,...
          btn = GEM_KEY_LEFT;
          // Button was in a pressed state during rotation of the knob, acting as a modifier to rotation action
          secondaryPressed = true;
        } else {
          // ...or GEM_KEY_UP otherwise
          btn = GEM_KEY_UP;
        }
      } else {
        // If channel B is high then the knob was rotated CW
        if (myKeyDetector.current == KEY_C) {
          // If push-button was pressed at that time, then treat this action as GEM_KEY_RIGHT,...
          btn = GEM_KEY_RIGHT;
          // Button was in a pressed state during rotation of the knob, acting as a modifier to rotation action
          secondaryPressed = true;
        } else {
          // ...or GEM_KEY_DOWN otherwise
          btn = GEM_KEY_DOWN;
        }
      }
      break;
    case KEY_C:
      // Button was pressed
      // Save current time as a time of the key press event
      keyPressTime = now;
      break;
  }
  switch (myKeyDetector.triggerRelease) {
    case KEY_C:
      // Button was released
      if (!secondaryPressed) {
        // If button was not used as a modifier to rotation action...
        if (now <= keyPressTime + keyPressDelay) {
          // ...and if not enough time passed since keyPressTime,
          // treat key that was pressed as Ok button
          btn = GEM_KEY_OK;
        }
      }
      secondaryPressed = false;
      cancelPressed = false;
      break;
  }
  // After keyPressDelay passed since keyPressTime
  if (now > keyPressTime + keyPressDelay) {
    switch (myKeyDetector.current) {
      case KEY_C:
        if (!secondaryPressed && !cancelPressed) {
          // If button was not used as a modifier to rotation action, and Cancel action was not triggered yet
          // Treat key that was pressed as Cancel button
          btn = GEM_KEY_CANCEL;
          cancelPressed = true;
        }
        break;
    }
  }
  return btn;
}

void loop() {
  // Get current time to use later on
  now = millis();

  // If menu is ready to accept button press...
  if (menu.readyForKey()) {
    byte key = detectEncoder();
    menu.registerKeyPress(key);
  }
}

void printData() {
  // If enablePrint flag is set to true (checkbox on screen is checked)...
  if (enablePrint) {
    // ...print the number to Serial
    char* label[] = {"Number is: ", "Nombre: ", "Nummer: "};
    Serial.print(label[lang]);
    Serial.println(number);
  } else {
    char* label[] = {"Printing is disabled, sorry:(", "L'impression est désactivée:(", "Drucken ist deaktiviert:("};
    Serial.println(label[lang]);
  }
}

void applyInvert() {
  menu.invertKeysDuringEdit(invert);
  // Print invert variable to Serial
  char* label[] = {"Invert: ", "Option inverser: ", "Option umkehren: "};
  Serial.print(label[lang]);
  Serial.println(invert);
}

void setLang() {
  char* label[] = {"Selected language: ", "Langue sélectionnée: ", "Ausgewählte sprache: "};
  Serial.print(label[lang]);
  
  // Serial.println(selectLangOptions[lang].name);
  // - or -
  Serial.println(selectLang.getSelectedOptionName(&lang));
  
  selectInvert.setOptions(selectInvertOptions[lang]);

  // Settings menu page
  menuPageSettings.setTitle(menuPageSettingsTitle[lang]);
  menuItemInvert.setTitle(menuItemInvertTitle[lang]);
  menuItemLang.setTitle(menuItemLangTitle[lang]);

  // Main menu page
  menuPageMain.setTitle(menuPageMainTitle[lang]);
  menuItemMainSettings.setTitle(menuItemMainSettingsTitle[lang]);
  menuItemInt.setTitle(menuItemIntTitle[lang]);
  menuItemBool.setTitle(menuItemBoolTitle[lang]);
  menuItemButton.setTitle(menuItemButtonTitle[lang]);
}