#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

#define OLED_RESET -1
#define OLED_ADDR 0x3C

#define DHTPIN 9
#define DHTTYPE DHT22

Adafruit_SSD1306 display(
  SCREEN_WIDTH,
  SCREEN_HEIGHT,
  &Wire,
  OLED_RESET
);

DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  dht.begin();

  if (!display.begin(SSD1306_SWITCHCAPVCC,
                     OLED_ADDR)) {
    Serial.println("OLED not found!");
    while (true);
  }

  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);
  display.setTextSize(1);
  display.setCursor(15, 20);
  display.println("DHT22 MONITOR");
  display.setCursor(15, 35);
  display.println("Arduino UNO");
  display.display();

  delay(1500);
}

void loop() {
  float temp = dht.readTemperature();
  float hum = dht.readHumidity();

  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);

  display.setTextSize(1);
  display.setCursor(20, 0);
  display.println("DHT22 MONITOR");

  display.drawLine(0, 12, 127, 12,
                   SSD1306_WHITE);

  if (isnan(temp) || isnan(hum)) {
    display.setCursor(0, 25);
    display.println("DHT22 READ ERROR");
    Serial.println("DHT22 Read Error");
  } else {
    display.setTextSize(1);
    display.setCursor(0, 20);
    display.println("Temperature:");

    display.setTextSize(2);
    display.setCursor(0, 32);
    display.print(temp, 1);
    display.println(" C");

    display.setTextSize(1);
    display.setCursor(0, 54);
    display.print("Humidity: ");
    display.print(hum, 1);
    display.print(" %");

    Serial.print("Temp: ");
    Serial.print(temp);
    Serial.print(" C | Humidity: ");
    Serial.print(hum);
    Serial.println(" %RH");
  }

  display.display();
  delay(2000);
}