#include <WiFi.h>
#include <PubSubClient.h>

#define LDR_PIN 34
#define LED_PIN 2

const char* ssid = "Wokwi-GUEST";
const char* password = "";

// sesuai thinsboard
const char* mqtt_server = "mqtt.thingsboard.cloud";
const char* mqtt_clid   = "wokwi_kelompok_8_unesa_ssl"; 
const char* mqtt_user   = "user_ssl";
const char* mqtt_pass   = "pass_ssl123";
const char* mqtt_topic  = "v1/devices/me/telemetry";

WiFiClient espClient;
PubSubClient client(espClient);
unsigned long lastMsg = 0;

void setup_wifi() {
  Serial.print("Connecting to WiFi");
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password, 6);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("\nWiFi connected");
}

void reconnect() {
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    if (client.connect(mqtt_clid, mqtt_user, mqtt_pass)) {
      Serial.println("Thingsboard is Connected !!");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(LDR_PIN, INPUT);
  pinMode(LED_PIN, OUTPUT);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
}

void loop() {
  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  unsigned long now = millis();
  if (now - lastMsg > 3000) { // kirim data tiap 3 detik
    lastMsg = now;

    int ldrValue = analogRead(LDR_PIN);
    String statusLampu = "MATI";
    
    // jika gelap (nilai analog ldr tinggi), lampu menyala
    if (ldrValue > 2000) { 
      digitalWrite(LED_PIN, HIGH);
      statusLampu = "AKTIF";
    } else {
      digitalWrite(LED_PIN, LOW);
      statusLampu = "MATI";
    }

    // json
    String payload = "{";
    payload += "\"intensitas_cahaya\":" + String(ldrValue) + ",";
    payload += "\"status_lampu\":\"" + statusLampu + "\"";
    payload += "}";

    client.publish(mqtt_topic, payload.c_str());
    Serial.print("Data Terkirim: ");
    Serial.println(payload);
  }
}