// ===============================================
// OLEDディスプレイの使い方(Adafruitライブラリ編)
// サンプル5:温湿度センサーの値をリアルタイム表示(Adafruit版)
// DHT22 を GPIO4 に接続
// ライブラリ: "DHT sensor library" (Adafruit)
// ボード: Arduino Uno R3/R4
// I2Cピン: SDA=A4, SCL=A5
// ===============================================
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>
#define DHT_PIN 4 // DHT22接続ピン
#define DHT_TYPE DHT22 // センサータイプ指定(DHT22)
// DHTセンサーのオブジェクト生成
DHT dht(DHT_PIN, DHT_TYPE);
// ディスプレイのオブジェクト生成
Adafruit_SSD1306 display(128, 64, &Wire, -1);
void setup() {
// I2C通信初期化
Wire.begin();
// ディスプレイの初期化
display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
// DHT22センサー初期化
dht.begin();
// 起動画面表示
display.clearDisplay();
display.setTextColor(SSD1306_WHITE);
display.setTextSize(1);
display.setCursor(0, 28);
display.print("DHT22 starting...");
display.display();
delay(2000);
}
void loop() {
// --- 測定 ---
float hum = dht.readHumidity();
float temp = dht.readTemperature();
// --- 描画(最初に表示内容は毎回クリアする) ---
display.clearDisplay();
if (isnan(hum) || isnan(temp)) {
// 読み取り失敗時の表示も用意しておく
display.setTextSize(1);
display.setCursor(0, 28);
display.print("Sensor error!");
} else {
// タイトルの描画
display.setTextSize(1);
display.setCursor(0, 0);
display.print("Temperature");
display.setCursor(0, 34);
display.print("Humidity");
// 測定値の描画
display.setTextSize(2);
display.setCursor(0, 12);
display.print(temp, 1);
display.print(" C");
display.setCursor(0, 46);
display.print(hum, 1);
display.print(" %");
// 右側に簡易バー(湿度 0-100% を高さ 60px に対応させる)
int bar_height = map((int)hum, 0, 100, 0, 60);
display.drawRect(118, 2, 8, 60, SSD1306_WHITE);
display.fillRect(118, 62 - bar_height, 8, bar_height, SSD1306_WHITE);
}
display.display();
// DHT22の測定は2秒間隔
delay(2000);
}
Loading
ssd1306
ssd1306