#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <DHT.h>
#include <ESP32Servo.h>
// ---------- pin ----------
#define DHT_PIN 4
#define TRIG_PIN 17
#define ECHO_PIN 16
#define GAS_PIN 34
#define LDR_PIN 35
#define PIR_PIN 19
#define RELAY_KIPAS 25
#define RELAY_LAMPU 15
#define SERVO_PIN 26
#define BUZZER_PIN 27
#define TOMBOL_MUTE 32
#define LED_R 14
#define LED_G 12
#define LED_B 13
Adafruit_SSD1306 oled(128, 64, &Wire, -1);
DHT dht(DHT_PIN, DHT22);
Servo servoVentilasi;
// ---------- batas-batas ----------
const float BATAS_SUHU = 35.0; // di atas ini kipas nyala
const float BATAS_SUHU_TURUN = 33.0; // trus mati lagi kalau udah di bawah ini
const float BATAS_LEMBAP = 75.0; // %RH, biar tidak karatan barangnya
const float LUX_GELAP = 50; // di bawah ini lampu nyala
const float LUX_TERANG = 150; // di atas ini lampu mati
// dasarnya pakai 0 ppm
const int GAS_WASPADA = 3762; // @ 1k ppm
const int GAS_BAHAYA = 3959; // @ 10k ppm
const int JARAK_DEKAT = 80; // dlm cm, lebih dekat dri ini dianggap mendekat
const int SERVO_TUTUP = 90;
const int SERVO_BUKA = 180;
// jam ngebengkel (jam gaib 1 s = 1 m)
const int JAM_BUKA = 4;
const int JAM_TUTUP = 23;
const int MENIT_MULAI = 22 * 60 + 45; // mulai 22:45 biar cepet sampai state tutup
const int MS_PER_MENIT = 1000;
// ---------- var ----------
float suhu = 0, lembap = 0, lux = 0;
int jarak = 999, gasMentah = 0, gasDasar = 0, menit = 0;
bool adaGerak = false, jamBengkel = true;
bool suhuPanas = false, lembapTinggi = false;
bool lampuNyala = false, kipasNyala = false;
bool mute = false, tombolSebelumnya = false;
int levelGas = 0, levelIntrusi = 0, levelAlarm = 0; // 0 aman, 1 waspada, 2 bahaya
int sudutServo = SERVO_TUTUP;
int nadaSekarang = 0;
unsigned long sensorTerakhir = 0, dhtTerakhir = 0, servoTerakhir = 0;
const char* namaLevel[] = {"AMAN", "WASPADA", "BAHAYA"};
// ---------- fungsi helper ----------
void setRGB(bool r, bool g, bool b) {
digitalWrite(LED_R, r);
digitalWrite(LED_G, g);
digitalWrite(LED_B, b);
}
// rumus lux dri wokwi (adc smkin tinggi = smkin gelap)
float hitungLux(int adc) {
if (adc <= 0) return 99999;
float v = adc / 4095.0 * 3.3;
float hambatan = 2000 * v / (1 - v / 3.3);
float hasil = pow(50e3 * pow(10, 0.7) / hambatan, 1 / 0.7);
return hasil > 99999 ? 99999 : hasil;
}
void cekTombol() {
bool ditekan = digitalRead(TOMBOL_MUTE) == LOW;
if (ditekan && !tombolSebelumnya) {
mute = !mute;
Serial.println(mute ? ">> Buzzer di-mute" : ">> Buzzer aktif lagi");
delay(20);
}
tombolSebelumnya = ditekan;
}
void bacaSensor() {
// dht22 min/dtk
if (dhtTerakhir == 0 || millis() - dhtTerakhir >= 2000) {
dhtTerakhir = millis();
float t = dht.readTemperature();
float h = dht.readHumidity();
if (!isnan(t)) suhu = t;
if (!isnan(h)) lembap = h;
}
digitalWrite(TRIG_PIN, LOW);
delayMicroseconds(2);
digitalWrite(TRIG_PIN, HIGH);
delayMicroseconds(10);
digitalWrite(TRIG_PIN, LOW);
long durasi = pulseIn(ECHO_PIN, HIGH, 30000);
jarak = durasi ? durasi * 0.034 / 2 : 999;
gasMentah = analogRead(GAS_PIN);
lux = hitungLux(analogRead(LDR_PIN));
adaGerak = digitalRead(PIR_PIN);
}
void hitungStatus() {
// jam simul
menit = (MENIT_MULAI + millis() / MS_PER_MENIT) % 1440;
jamBengkel = (menit >= JAM_BUKA * 60 && menit < JAM_TUTUP * 60);
// suhu & lembap pakai kipas aj
if (suhu > BATAS_SUHU) suhuPanas = true;
else if (suhu < BATAS_SUHU_TURUN) suhuPanas = false;
lembapTinggi = lembap > BATAS_LEMBAP;
// lampu otomatis
if (lux < LUX_GELAP) lampuNyala = true;
else if (lux > LUX_TERANG) lampuNyala = false;
levelGas = gasMentah > GAS_BAHAYA ? 2 : gasMentah > GAS_WASPADA ? 1 : 0;
// orang di ruangan luar jam bengkel
bool mendekat = jarak < JARAK_DEKAT;
if (jamBengkel) levelIntrusi = 0;
else if (adaGerak && mendekat) levelIntrusi = 2;
else if (adaGerak || mendekat) levelIntrusi = 1;
else levelIntrusi = 0;
levelAlarm = max(levelGas, levelIntrusi);
if (levelAlarm == 0) mute = false; // kondisi aman, reset mute
}
void tampilOLED() {
oled.clearDisplay();
oled.setTextSize(1);
oled.setTextColor(WHITE);
oled.setCursor(0, 0);
oled.printf("LABSENTRY! %02d:%02d", menit / 60, menit % 60);
oled.drawLine(0, 9, 127, 9, WHITE);
oled.setCursor(0, 12);
oled.printf("T:%.1fC H:%.0f%% %s\n", suhu, lembap, suhuPanas ? "PANAS" : "");
oled.printf("Gas:%d %s\n", gasMentah, namaLevel[levelGas]);
oled.printf("Lux:%d Lampu:%s\n", (int)lux, lampuNyala ? "ON" : "OFF");
if (jarak >= 400) oled.print("Jarak:-- ");
else oled.printf("Jarak:%dcm ", jarak);
oled.printf("PIR:%s\n", adaGerak ? "ADA" : "-");
oled.printf("Jam:%s Kipas:%s\n", jamBengkel ? "BUKA" : "TUTUP", kipasNyala ? "ON" : "OFF");
oled.printf("Alarm:%s%s", namaLevel[levelAlarm], mute ? " (MUTE)" : "");
oled.display();
}
// serial monitor
void cetakSerial() {
Serial.printf("T=%.1f H=%.0f gas=%d (dasar %d) lux=%.0f jarak=%d pir=%d jam=%02d:%02d | gas L%d intrusi L%d\n",
suhu, lembap, gasMentah, gasDasar, lux, jarak, adaGerak,
menit / 60, menit % 60, levelGas, levelIntrusi);
}
void aturAktuator() {
unsigned long skrg = millis();
// kipas panas / lembap / gas
kipasNyala = suhuPanas || lembapTinggi || levelGas >= 1;
digitalWrite(RELAY_KIPAS, kipasNyala);
digitalWrite(RELAY_LAMPU, lampuNyala);
// servo ventilasi terbuka kalau gas bahaya, geraknya 1 deg/15 ms
int sudutTarget = (levelGas == 2) ? SERVO_BUKA : SERVO_TUTUP;
if (sudutServo != sudutTarget && skrg - servoTerakhir >= 15) {
servoTerakhir = skrg;
sudutServo += (sudutServo < sudutTarget) ? 1 : -1;
servoVentilasi.write(sudutServo);
}
// rgb led (merah = suhu/lembap, hijau = gas, biru = intrusi)
// merah+hijau = kuning, merah+biru = magenta, hijau+biru = cyan, semua = putih
// level bahaya = kedip epilepsi
bool kedip = (skrg / 200) % 2;
bool r = suhuPanas || lembapTinggi;
bool g = levelGas > 0 && (levelGas == 1 || kedip);
bool b = levelIntrusi > 0 && (levelIntrusi == 1 || kedip);
if (!r && !g && !b) r = g = b = (skrg % 2000) < 10;
setRGB(r, g, b);
// buzzer (waspada = beep pendek, bahaya = sirine)
int nada = 0;
if (!mute) {
if (levelAlarm == 1) {
int p = skrg % 1500;
if (p < 120) nada = 880;
else if (p < 240) nada = 660;
} else if (levelAlarm == 2) {
nada = 600 + ((skrg % 800) / 20) * 20;
}
}
if (nada != nadaSekarang) {
nadaSekarang = nada;
if (nada) tone(BUZZER_PIN, nada);
else noTone(BUZZER_PIN);
}
}
void setup() {
Serial.begin(115200);
pinMode(TRIG_PIN, OUTPUT);
pinMode(ECHO_PIN, INPUT);
pinMode(PIR_PIN, INPUT);
pinMode(TOMBOL_MUTE, INPUT_PULLUP);
pinMode(RELAY_KIPAS, OUTPUT);
pinMode(RELAY_LAMPU, OUTPUT);
pinMode(BUZZER_PIN, OUTPUT);
pinMode(LED_R, OUTPUT);
pinMode(LED_G, OUTPUT);
pinMode(LED_B, OUTPUT);
digitalWrite(RELAY_KIPAS, LOW);
digitalWrite(RELAY_LAMPU, LOW);
setRGB(0, 0, 0);
servoVentilasi.attach(SERVO_PIN);
servoVentilasi.write(SERVO_TUTUP);
dht.begin();
if (!oled.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
Serial.println("OLED gagal init!");
}
// layar booting & calib gas
oled.clearDisplay();
oled.setTextColor(WHITE);
oled.setTextSize(2);
oled.setCursor(10, 12);
oled.print("LabSentry!");
oled.setTextSize(1);
oled.setCursor(19, 36);
oled.print("smart lab guard");
oled.drawRect(14, 50, 100, 8, WHITE);
long total = 0;
for (int i = 0; i < 10; i++) {
total += analogRead(GAS_PIN);
oled.fillRect(14, 50, (i + 1) * 10, 8, WHITE);
oled.display();
delay(100);
}
gasDasar = total / 10;
Serial.printf("LabSentry siap bosq!!! gas dasar = %d\n", gasDasar);
}
void loop() {
cekTombol();
if (millis() - sensorTerakhir >= 500) {
sensorTerakhir = millis();
bacaSensor();
hitungStatus();
tampilOLED();
cetakSerial();
}
aturAktuator();
}Loading
esp32-devkit-c-v4
esp32-devkit-c-v4
Loading
ssd1306
ssd1306
(Lampu)
(Exhaust Fan)