//
// Touch Reactive Robot Eyes – ESP32-C3 & OLED
//
// Interactive robot eyes controlled by a TTP223B capacitive touch sensor.
//
// The project uses an ESP32-C3 SuperMini and a 128x64 SSD1306 OLED
// display to create animated robot eyes.
//
// The pupils move randomly from left to right, while the eyes blink
// periodically. When the touch sensor is activated, the eyes change
// their expression to an angry look.
//
// The TTP223B module includes its own onboard LED indicator,
// which lights up when the sensor detects a touch.
//
// Components:
// - ESP32-C3 SuperMini
// - SSD1306 OLED Display (128x64, I2C)
// - TTP223B Capacitive Touch Sensor with onboard LED
//
// Simulated with Wokwi.
//
// ------------------------------------------------------------
//
// Occhi Robot Reattivi al Tocco – ESP32-C3 e OLED
//
// Un progetto interattivo che realizza occhi animati su un display
// OLED SSD1306 da 128x64 pixel, controllato da una scheda ESP32-C3.
//
// Le pupille si muovono casualmente verso destra e sinistra,
// mentre gli occhi sbattono periodicamente le palpebre.
//
// Quando viene attivato il sensore capacitivo TTP223B,
// gli occhi cambiano espressione assumendo uno sguardo arrabbiato.
//
// Il modulo TTP223B dispone di un LED integrato che si accende
// quando viene rilevato un tocco.
//
// Componenti utilizzati:
// - ESP32-C3 SuperMini
// - Display OLED SSD1306 (128x64, I2C)
// - Sensore capacitivo TTP223B con LED integrato
//
// Progetto realizzato e simulato con Wokwi.
//
// Author: Adrirobot
// Website: https://www.adrirobot.it
//

#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

// Configurazione pin ESP32-C3 SuperMini
#define I2C_SDA 8
#define I2C_SCL 9

const int TOUCH_PIN = 4;

#define OLED_RESET -1

Adafruit_SSD1306 display(
  SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET
);

// Gestione tempistiche
unsigned long lastBlinkTime = 0;
const unsigned long blinkInterval = 3000;

unsigned long lastLookTime = 0;
const unsigned long lookInterval = 2500;

// Stati del movimento occhi:
// 0 = Centro, 1 = Sinistra, 2 = Destra
int eyeDirection = 0;
int pupilOffset = 0;

void setup() {

  pinMode(TOUCH_PIN, INPUT_PULLDOWN);

  Wire.begin(I2C_SDA, I2C_SCL);

  if (!display.begin(SSD1306_SWITCHCAPVCC, 0x3C)) {
    for (;;) {}
  }

  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);

  // Inizializza il generatore casuale
  randomSeed(analogRead(0));
}

void loop() {

  int touchState = digitalRead(TOUCH_PIN);

  if (touchState == HIGH) {

    // REAZIONE AL TOCCO: occhi arrabbiati
    pupilOffset = 0;
    disegnaOcchiToccati();

    delay(100);

  } else {

    // COMPORTAMENTO NORMALE

    // 1. Movimento casuale delle pupille
    if (millis() - lastLookTime > lookInterval) {

      eyeDirection = random(0, 3);

      if (eyeDirection == 0) pupilOffset = 0;
      if (eyeDirection == 1) pupilOffset = -6;
      if (eyeDirection == 2) pupilOffset = 6;

      lastLookTime = millis();
    }

    // 2. Gestione battito di ciglia
    if (millis() - lastBlinkTime > blinkInterval) {

      sbattiPalpebre();
      lastBlinkTime = millis();

    } else {

      disegnaOcchiNormali();
    }
  }
}

// Funzione: occhi normali con pupille mobili
void disegnaOcchiNormali() {

  display.clearDisplay();

  // Occhio sinistro
  display.fillCircle(35, 32, 20, SSD1306_WHITE);
  display.fillCircle(35 + pupilOffset, 32, 8, SSD1306_BLACK);

  // Occhio destro
  display.fillCircle(93, 32, 20, SSD1306_WHITE);
  display.fillCircle(93 + pupilOffset, 32, 8, SSD1306_BLACK);

  display.display();
}

// Funzione: animazione battito di ciglia
void sbattiPalpebre() {

  display.clearDisplay();

  // Linee orizzontali per simulare le palpebre chiuse
  display.drawFastHLine(15, 32, 40, SSD1306_WHITE);
  display.drawFastHLine(73, 32, 40, SSD1306_WHITE);

  display.display();

  delay(150);
}

// Funzione: occhi arrabbiati quando viene toccato il sensore
void disegnaOcchiToccati() {

  display.clearDisplay();

  // Occhio sinistro
  display.fillCircle(35, 32, 20, SSD1306_WHITE);
  display.fillCircle(35, 32, 8, SSD1306_BLACK);

  display.fillTriangle(
    10, 12, 60, 12, 10, 25, SSD1306_BLACK
  );

  // Occhio destro
  display.fillCircle(93, 32, 20, SSD1306_WHITE);
  display.fillCircle(93, 32, 8, SSD1306_BLACK);

  display.fillTriangle(
    118, 12, 68, 12, 118, 25, SSD1306_BLACK
  );

  display.display();
}