// Predictor de Smith discreto con PI[z] - Ts = 0.5 s, retardo = 5 muestras
// Lilibeth Fontalvo y Sandy Uribe
const unsigned long TS_US = 500000UL; // muestreador: Ts = 0.5 s
const float Ts = 0.5f;
const int D = 5; // theta/Ts = 2.5/0.5
const float a = 0.778800783f; // exp(-Ts/tau)
const float b = 0.442398434f; // K*(1-a)
const float Kp = 1.0f, Ki = 0.5f;
const float r = 1.0f; // escalon unitario
float Hp[D + 1], Hm[D + 1]; // historiales planta / modelo (sin retardo)
float u_prev = 0.0f, I_acc = 0.0f;
int k = 0;
unsigned long next_tick;
void setup() {
Serial.begin(115200);
for (int i = 0; i <= D; i++) { Hp[i] = 0.0f; Hm[i] = 0.0f; }
Serial.println("k,t,y,u");
next_tick = micros() + TS_US;
}
void loop() {
// Muestreador determinista: instante absoluto, sin deriva acumulada
while ((long)(micros() - next_tick) < 0) { }
next_tick += TS_US;
// 1) Planta y modelo: G0(z) = b/(z-a), usando u[k-1]
float xp = a * Hp[0] + b * u_prev;
float xm = a * Hm[0] + b * u_prev;
for (int i = D; i > 0; i--) { Hp[i] = Hp[i - 1]; Hm[i] = Hm[i - 1]; }
Hp[0] = xp; Hm[0] = xm;
float y = Hp[D]; // salida real (con retardo)
float ym0 = Hm[0]; // modelo sin retardo
float ymd = Hm[D]; // modelo con retardo
// 2) Realimentacion del Predictor de Smith
float fb = y + ym0 - ymd;
float e = r - fb;
// 3) PI[z] (integral Backward Euler)
I_acc += Ki * Ts * e;
float u = Kp * e + I_acc;
Serial.print(k); Serial.print(',');
Serial.print(k * Ts, 1); Serial.print(',');
Serial.print(y, 4); Serial.print(',');
Serial.println(u, 4);
u_prev = u;
k++;
if (k > 60) while (true) { } // 30 s y se detiene
}