/*
* Project 6: Biometric Attendance & Secure Lab Access System (UGV Campus)
* Student: Joyeta Das ID: 12411029
*
* Wiring:
* Fingerprint TX -> D2, RX -> D3 Servo -> D9 Buzzer -> D8
* Green LED -> D5, Red LED -> D6 Admin button -> D4 and GND
* LCD (I2C): SDA -> A4, SCL -> A5
*
* In Wokwi: hold the green TOUCH button = finger on the sensor.
* Click the sensor chip to choose whose finger (1-20) and the scan quality.
*/
#include <Adafruit_Fingerprint.h>
#include <SoftwareSerial.h>
#include <Servo.h>
#include <LiquidCrystal_I2C.h>
#define ADMIN_BTN 4
#define GREEN_LED 5
#define RED_LED 6
#define BUZZER 8
#define SERVO_PIN 9
#define LOCKED_ANGLE 0
#define UNLOCKED_ANGLE 90
#define RELOCK_TIME 5000 // lock again after 5 seconds
#define MIN_CONFIDENCE 80 // lower score = access denied
SoftwareSerial fpSerial(2, 3); // RX, TX
Adafruit_Fingerprint finger(&fpSerial);
Servo lockServo;
LiquidCrystal_I2C lcd(0x27, 16, 2);
bool doorOpen = false;
unsigned long unlockTime = 0;
void showMessage(String line1, String line2) {
lcd.clear();
lcd.print(line1);
lcd.setCursor(0, 1);
lcd.print(line2);
}
// Finish the beep before using the sensor again
void beep(int freq, int ms) {
tone(BUZZER, freq);
delay(ms);
noTone(BUZZER);
}
void lockDoor() {
lockServo.write(LOCKED_ANGLE);
digitalWrite(GREEN_LED, LOW);
doorOpen = false;
showMessage("Door Locked", "Place finger");
}
void unlockDoor() {
lockServo.write(UNLOCKED_ANGLE);
digitalWrite(GREEN_LED, HIGH);
doorOpen = true;
unlockTime = millis();
}
void waitForRemove() {
while (finger.getImage() != FINGERPRINT_NOFINGER) delay(50);
}
// Wait for a finger and turn its image into a template in slot 1 or 2
void captureFinger(int slot) {
while (finger.getImage() != FINGERPRINT_OK || finger.image2Tz(slot) != FINGERPRINT_OK) {
delay(50);
}
}
// Enrollment: scan the same finger 2 times, make one template, save it as id
void enrollFinger(int id) {
showMessage("Enroll ID " + String(id), "Place finger");
captureFinger(1);
beep(1500, 100);
showMessage("Remove finger", "");
waitForRemove();
showMessage("Place same", "finger again");
captureFinger(2);
if (finger.createModel() == FINGERPRINT_OK && finger.storeModel(id) == FINGERPRINT_OK) {
showMessage("Enrolled!", "Saved as ID " + String(id));
Serial.print("New user enrolled, ID: ");
Serial.println(id);
} else {
showMessage("Enroll failed", "Try again");
}
beep(1500, 300);
waitForRemove();
delay(1500);
}
// Hidden admin button: only the admin (ID 1) can add new users
void adminMode() {
finger.getTemplateCount();
int newId = finger.templateCount + 1; // next free ID
if (newId > 1) { // an admin already exists, so check the admin finger first
showMessage("ADMIN MODE", "Admin finger...");
captureFinger(1);
bool isAdmin = finger.fingerSearch() == FINGERPRINT_OK &&
finger.fingerID == 1 && finger.confidence >= MIN_CONFIDENCE;
waitForRemove();
if (!isAdmin) {
showMessage("Not admin!", "Enroll blocked");
Serial.println("Enrollment blocked: not admin");
beep(300, 800);
delay(1500);
return;
}
}
enrollFinger(newId); // the very first user becomes the admin (ID 1)
}
void setup() {
Serial.begin(9600);
pinMode(ADMIN_BTN, INPUT_PULLUP);
pinMode(GREEN_LED, OUTPUT);
pinMode(RED_LED, OUTPUT);
lockServo.attach(SERVO_PIN);
lcd.init();
lcd.backlight();
// Check communication with the fingerprint sensor
finger.begin(57600);
if (finger.verifyPassword()) {
Serial.println("Fingerprint sensor found");
} else {
Serial.println("Fingerprint sensor NOT found");
showMessage("Sensor error", "");
while (true);
}
Serial.println("Student: Joyeta Das (12411029)");
Serial.println("Attendance log:");
lockDoor();
}
void loop() {
// Admin button -> enrollment mode
if (digitalRead(ADMIN_BTN) == LOW) {
adminMode();
lockDoor();
}
// Auto re-lock
if (doorOpen && millis() - unlockTime >= RELOCK_TIME) {
lockDoor();
}
// Wait for a finger with a clear image
if (finger.getImage() != FINGERPRINT_OK) return;
if (finger.image2Tz() != FINGERPRINT_OK) return;
// Search the saved fingerprints and check the confidence score
if (finger.fingerSearch() == FINGERPRINT_OK && finger.confidence >= MIN_CONFIDENCE) {
unlockDoor();
showMessage("Access Granted", "ID: " + String(finger.fingerID));
beep(2000, 300);
// Attendance log: user ID + time since power-on
Serial.print("Time: ");
Serial.print(millis() / 1000);
Serial.print(" s | User ID: ");
Serial.print(finger.fingerID);
Serial.print(" | Confidence: ");
Serial.println(finger.confidence);
} else {
digitalWrite(RED_LED, HIGH);
showMessage("Access Denied", "");
Serial.println("Access denied");
beep(300, 800);
digitalWrite(RED_LED, LOW);
lockDoor(); // door stays locked
}
waitForRemove();
}